Yan Cui
I help clients go faster for less using serverless technologies.
ps. look out for all my other solutions for Advent of Code challenges here.
Day 10
See details of the challenge here.
The input for today’s challenge looks like this:
bot 171 gives low to bot 4 and high to bot 84
bot 1 gives low to bot 117 and high to bot 81
bot 82 gives low to bot 209 and high to bot 103
bot 128 gives low to bot 56 and high to bot 91
value 23 goes to bot 8
bot 7 gives low to bot 148 and high to bot 22…
To parse this input file, it feels to me that Regex is the best bet; and to answer the challenge we can run the simulation until one of the bots have both value-17 and value-61 chips.
| open System | |
| open System.Collections.Generic | |
| open System.IO | |
| open System.Text.RegularExpressions | |
| let input = File.ReadAllLines (__SOURCE_DIRECTORY__ + "/Day10Input.txt") | |
| type Target = | |
| | Bot of int | |
| | Output of int | |
| let (|Regex|_|) pattern input = | |
| let m = Regex.Match(input, pattern) | |
| if m.Success then Some(List.tail [ for g in m.Groups -> g.Value ]) | |
| else None | |
| let (|Int|) x = Int32.Parse x | |
| let (|Target|) = function | "bot" -> Bot | _ -> Output | |
| type Bot = | |
| { | |
| Number : int | |
| Microchips : int list | |
| LowTarget : Target | |
| HiTarget : Target | |
| } | |
| let events = | |
| let bots = new Dictionary<int, Bot>() | |
| input | |
| |> Array.sort | |
| |> Array.iter (fun line -> | |
| match line with | |
| | Regex "bot (\d*) gives low to (bot|output) (\d*) and high to (bot|output) (\d*)" | |
| [ Int botN; Target lowT; Int lowN; Target hiT; Int hiN ] -> | |
| let bot = | |
| { | |
| Number = botN | |
| Microchips = [] | |
| LowTarget = lowT lowN | |
| HiTarget = hiT hiN | |
| } | |
| bots.Add(botN, bot) | |
| | Regex "value (\d*) goes to bot (\d*)" [ Int value; Int botN ] -> | |
| let bot = bots.[botN] | |
| bots.[botN] <- { bot with Microchips = value::bot.Microchips }) | |
| let give value = function | |
| | Bot botN -> | |
| let bot = bots.[botN] | |
| bots.[botN] <- { bot with Microchips = value::bot.Microchips } | |
| | _ -> () | |
| let botsWithTwo = | |
| bots | |
| |> Seq.map (fun kvp -> kvp.Value) | |
| |> Seq.filter (fun bot -> bot.Microchips.Length = 2) | |
| seq { | |
| while Seq.length botsWithTwo > 0 do | |
| for bot in (Array.ofSeq botsWithTwo) do | |
| let [ lowVal; hiVal ] = bot.Microchips |> List.sort | |
| bots.[bot.Number] <- { bot with Microchips = [] } | |
| give lowVal bot.LowTarget | |
| give hiVal bot.HiTarget | |
| yield bot.Number, (bot.LowTarget, lowVal), (bot.HiTarget, hiVal) | |
| } | |
| let part1 = | |
| events | |
| |> Seq.pick (fun (botN, (_, lowVal), (_, hiVal)) -> | |
| if lowVal = 17 && hiVal = 61 then Some botN else None) |
The bulk of the work happens in the definition for the events sequence. I decided to use a Dictionary to track the current state of the bots, but I didn’t want to expose that mutability to the outside hence why it was declare inside the definition for events.
Ultimately events is a sequence of tuples telling us which bot gave low and hi values to which targets as we simulate the behaviour of the bots. It makes answering both parts of the challenge really simple.
Part 2
What do you get if you multiply together the values of one chip in each of
outputs 0, 1, and 2?
We can consume the same events sequence we created earlier, and collect any values that are given to output 0, 1 and 2 and multiply them.
| let part2 = | |
| let isOutput0To2 = function | |
| | Output 0 | Output 1 | Output 2 -> true | |
| | _ -> false | |
| events | |
| |> Seq.collect (fun (botN, (lowTarget, lowVal), (hiTarget, hiVal)) -> | |
| seq { | |
| if isOutput0To2 lowTarget then yield lowVal | |
| if isOutput0To2 hiTarget then yield hiVal | |
| }) | |
| |> Seq.take 3 | |
| |> Seq.reduce (*) |
Links
- Day 10 challenge description
- Advent of Code 2015
- Solution for Day 9
- All my F# solutions for Advent of Code
- Github repo
Whenever you’re ready, here are 3 ways I can help you:
- Production-Ready Serverless: Join 20+ AWS Heroes & Community Builders and 1000+ other students in levelling up your serverless game. This is your one-stop shop for quickly levelling up your serverless skills.
- I help clients launch product ideas, improve their development processes and upskill their teams. If you’d like to work together, then let’s get in touch.
- Join my community on Discord, ask questions, and join the discussion on all things AWS and Serverless.
Pingback: Advent of Code F# – Day 21 | theburningmonk.com