Project Euler – Problem 87 Solution

Problem

The smallest number expressible as the sum of a prime square, prime cube, and prime fourth power is 28. In fact, there are exactly four numbers below fifty that can be expressed in such a way:

28 = 2² + 2³ + 2⁴

33 = 3² + 2³ + 2⁴

49 = 5² + 2³ + 2⁴

47 = 2² + 3³ + 2⁴

How many numbers below fifty million can be expressed as the sum of a prime square, prime cube, and prime fourth power?

Solution

// generate all prime numbers under <= this max
let max = int64(sqrt(double(50000000L)))

// initialise the list with 2 which is the only even number in the sequence
let mutable primeNumbers = &#91;2L&#93;

// only check the prime numbers which are <= the square root of the number n
let hasDivisor n =
    primeNumbers
    |> Seq.takeWhile (fun n' -> n' <= int64(sqrt(double(n))))
    |> Seq.exists (fun n' -> n % n' = 0L)

// only check odd numbers <= max
let potentialPrimes = Seq.unfold (fun n -> if n > max then None else Some(n, n+2L)) 3L

// populate the prime numbers list
for n in potentialPrimes do if not(hasDivisor n) then primeNumbers <- primeNumbers @ &#91;n&#93;

// use the same hasDivisor function instead of the prime numbers list as it offers
// far greater coverage as the number n is square rooted so this function can
// provide a valid test up to max*max
let isPrime n = if n = 1L then false else not(hasDivisor(n))

let answer =
    primeNumbers
    |> Seq.collect (fun n ->
        primeNumbers 
        |> Seq.map (fun n' -> pown n 2 + pown n' 3) 
        |> Seq.takeWhile (fun sum -> sum < 50000000L))
    |> Seq.collect (fun sum ->
        primeNumbers 
        |> Seq.map (fun n -> sum + pown n 4) 
        |> Seq.takeWhile (fun sum' -> sum' < 50000000L))
    |> Seq.distinct
    |> Seq.length

The biggest prime that can appear in the equation is equals to the square root of 50000000 – 8 – 16, which, incidentally is just over 7000, so the numbers of primes involved is reasonably small which bodes well for a fast solution!

The logic in this solution is otherwise simple, using the cached prime numbers list to first generate numbers (< 50 million) that can be written as the sum of a prime square and prime cube; then for each number see if we can add a prime fourth power and get a sum less than 50 million.

One thing that caught me out initially was the need to search for distinct numbers as some of these numbers do overlap, but otherwise this is a solution which runs happily under 3 seconds.